Sunday, August 12, 2007
patch for juno and dex tracker bugs ( csound )
I started to do some testing of dex tracker... seems like the major bug of having it not saving the entire row when you type it in is still there. If you see an e (short for end) it should be deleted it isn't used in csound 5 anyway.. I am noticing some usability issues with some of the instruments on the csound disk.. In one case it only plays if I do not change the .sco it came with.. I reorganised the disk into different catagories and started to work with one that I had in the emulation catagory. ..
sr = 44100
kr = 4410
ksmps = 10
nchnls = 1
; my shot at a simulated analog synth, largely based on my Juno
; but with more quantitative editing of parameters (and more flexible
; ones in some cases).
; The envelope is sort of cheesy, and the resonance seems a little weird
; but other than that I think it's pretty cool.
; idetune really helped fatten it up, but I might want to slap some chorus
; on the end too. And idetune only works if you're using the sub oscillator.
instr 1
ilforate = 5.1 ; LFO SPEED IN Hz
ilfodelay = 0 ; TIME BEFORE LFO STARTS, IN SECONDS
ilfopitch = 0 ; EFFECT LFO HAS ON PITCH (FROM 0 TO 1)
isawlvl = 0.75 ; LEVEL OF SAWTOOTH WAVEFORM
isublvl = 0.5 ; LEVEL OF SUB WAVEFORM
idetune = 0.005 ; HOW MUCH TO DETUNE SUB FROM SAWTOOTH
inoislvl = 0 ; LEVEL OF RANDOM NOISE GENERATOR
ihpffrq = 0 ; CUTOFF OF GLOBAL HIGH PASS FILTER
ivcffrq = 600 ; CUTOFF OF GLOBAL LOW PASS FILTER
ires = 0 ; RESONANCE LEVEL (NEEDS TO BE REALLY LOW LIKE 0.001)
ienvflt = 100 ; MAX CHANGE IN LPF CUTOFF BY ENVELOPE
ilfoflt = 50 ; MAX CHANGE IN LPF CUTOFF BY LFO
ikbdflt = 0.1 ; RELATIVE CHANGE IN LPF CUTOFF TO PITCH
iattack = 0.2 ; ATTACK LENGTH COMPARED TO NOTE DURATION
idecay = 0.1 ; DECAY LENGTH COMPARED TO NOTE DURATION
isustain = 0.8 ; SUSTAIN LEVEL (1 IS FULL STRENGTH)
irelease = 0.2 ; RELEASE LENGTH COMPARED TO NOTE DURATION
isteady = 1 - (iattack + idecay + irelease) ; LENGTH OF SUSTAIN LEVEL
; THE OSCILLATORS
klfoenv linseg 0, ilfodelay/2, 0, ilfodelay/2, 1, 1, 1
klfo oscil 1, ilforate, 1
asaw oscili isawlvl, p5 * (1+ klfo*ilfopitch), 3
asub oscil isublvl, p5/2 * (1 + idetune) * (1 + klfo*ilfopitch), 4
anoise rand inoislvl
awaves = asaw+asub+anoise
; THE ENVELOPE
kenv linseg 0, p3*iattack, 1, p3*idecay, isustain, p3*isteady, isustain, p3*irelease, 0
; THE FILTERS
ahpfed atone awaves, ihpffrq
klpfcut = ivcffrq + p5 * ikbdflt + ienvflt * kenv + ilfoflt * klfo
alpfed tone ahpfed, klpfcut
aresond reson ahpfed*ires, klpfcut, klpfcut/10
aflted = alpfed + aresond
aout = p4*kenv*aflted
out aout
endin
This is the first patch that I have created for the juno. You would just load in the patch and then modify or leave the same as you wish. I have found you get a realy good sound when you run more than one note at a time.
pad.sco
f 1 0 1024 10 1
f 3 0 1024 7 -1 1024 1
f 4 0 1024 7 -1 512 -1 0 1 512 1
;inst start dur ?? freq ;
i1 1 5 1600 250
i1 1.1 1 1900 300
i1 7 1 2000 500
This is the start of beta of a song as the author says it could probily use something to fatten the sound up... Having it as part of the instrument may be something that I would try to do (easier to deal with that connecting instruments when it comes to creating reusable patch's) heres the score
f 1 0 1024 10 1
f 3 0 1024 7 -1 1024 1
f 4 0 1024 7 -1 512 -1 0 1 512 1
;inst start dur ?? freq ;
i1 1 1 3000 330
i1 1.9 .2 3050 310
i1 2 1 3100 340
i1 3 2 3200 350
i1 4 1 1500 140
i1 4.9 .2 3300 300
i1 5 5 1600 250
i1 5.1 1 1900 330
i1 7 1 2000 500
sr = 44100
kr = 4410
ksmps = 10
nchnls = 1
; my shot at a simulated analog synth, largely based on my Juno
; but with more quantitative editing of parameters (and more flexible
; ones in some cases).
; The envelope is sort of cheesy, and the resonance seems a little weird
; but other than that I think it's pretty cool.
; idetune really helped fatten it up, but I might want to slap some chorus
; on the end too. And idetune only works if you're using the sub oscillator.
instr 1
ilforate = 5.1 ; LFO SPEED IN Hz
ilfodelay = 0 ; TIME BEFORE LFO STARTS, IN SECONDS
ilfopitch = 0 ; EFFECT LFO HAS ON PITCH (FROM 0 TO 1)
isawlvl = 0.75 ; LEVEL OF SAWTOOTH WAVEFORM
isublvl = 0.5 ; LEVEL OF SUB WAVEFORM
idetune = 0.005 ; HOW MUCH TO DETUNE SUB FROM SAWTOOTH
inoislvl = 0 ; LEVEL OF RANDOM NOISE GENERATOR
ihpffrq = 0 ; CUTOFF OF GLOBAL HIGH PASS FILTER
ivcffrq = 600 ; CUTOFF OF GLOBAL LOW PASS FILTER
ires = 0 ; RESONANCE LEVEL (NEEDS TO BE REALLY LOW LIKE 0.001)
ienvflt = 100 ; MAX CHANGE IN LPF CUTOFF BY ENVELOPE
ilfoflt = 50 ; MAX CHANGE IN LPF CUTOFF BY LFO
ikbdflt = 0.1 ; RELATIVE CHANGE IN LPF CUTOFF TO PITCH
iattack = 0.2 ; ATTACK LENGTH COMPARED TO NOTE DURATION
idecay = 0.1 ; DECAY LENGTH COMPARED TO NOTE DURATION
isustain = 0.8 ; SUSTAIN LEVEL (1 IS FULL STRENGTH)
irelease = 0.2 ; RELEASE LENGTH COMPARED TO NOTE DURATION
isteady = 1 - (iattack + idecay + irelease) ; LENGTH OF SUSTAIN LEVEL
; THE OSCILLATORS
klfoenv linseg 0, ilfodelay/2, 0, ilfodelay/2, 1, 1, 1
klfo oscil 1, ilforate, 1
asaw oscili isawlvl, p5 * (1+ klfo*ilfopitch), 3
asub oscil isublvl, p5/2 * (1 + idetune) * (1 + klfo*ilfopitch), 4
anoise rand inoislvl
awaves = asaw+asub+anoise
; THE ENVELOPE
kenv linseg 0, p3*iattack, 1, p3*idecay, isustain, p3*isteady, isustain, p3*irelease, 0
; THE FILTERS
ahpfed atone awaves, ihpffrq
klpfcut = ivcffrq + p5 * ikbdflt + ienvflt * kenv + ilfoflt * klfo
alpfed tone ahpfed, klpfcut
aresond reson ahpfed*ires, klpfcut, klpfcut/10
aflted = alpfed + aresond
aout = p4*kenv*aflted
out aout
endin
This is the first patch that I have created for the juno. You would just load in the patch and then modify or leave the same as you wish. I have found you get a realy good sound when you run more than one note at a time.
pad.sco
f 1 0 1024 10 1
f 3 0 1024 7 -1 1024 1
f 4 0 1024 7 -1 512 -1 0 1 512 1
;inst start dur ?? freq ;
i1 1 5 1600 250
i1 1.1 1 1900 300
i1 7 1 2000 500
This is the start of beta of a song as the author says it could probily use something to fatten the sound up... Having it as part of the instrument may be something that I would try to do (easier to deal with that connecting instruments when it comes to creating reusable patch's) heres the score
f 1 0 1024 10 1
f 3 0 1024 7 -1 1024 1
f 4 0 1024 7 -1 512 -1 0 1 512 1
;inst start dur ?? freq ;
i1 1 1 3000 330
i1 1.9 .2 3050 310
i1 2 1 3100 340
i1 3 2 3200 350
i1 4 1 1500 140
i1 4.9 .2 3300 300
i1 5 5 1600 250
i1 5.1 1 1900 330
i1 7 1 2000 500
Labels: csound, csound patch, juno
# posted by Unknown @ 11:11 PM 
